一、前言

1、能够使用Arduino的软串口控制Esp8266接入网络，可以看看我的前两个博客。

2、了解MQTT协议，阿里云搭建MQTT服务器。

3、需要的库文件

WiFiEsp库是一个Arduino的封装好AT指令的WiFi操作库，可以使用Arduino的软串口操作

PubSubClient是一个用于Esp8266发布/订阅MQTT消息的库。

1链接：https://pan.baidu.com/s/1mAaIbO3-SzVaN-jaaFwVbw 
2提取码：ol2p

4、修改Esp8266串口波特率为9600

使用AT指令输入AT+UART_DEF=9600,8,1,0,0，如何使用AT指令请看Arduino Esp8266开发 （一）AT指令调试

5、参考的文章网址

二、Arduino代码

1#include "DHT.h"
2#include <WiFiEspClient.h>
3#include <WiFiEsp.h>
4#include <WiFiEspUdp.h>
5#include <PubSubClient.h>
6#include "SoftwareSerial.h"
7
8#define WIFI_AP "xxxx"	//你家Wifi名称
9#define WIFI_PASSWORD "****"	//密码
10
11// DHT
12#define DHTPIN 10		//DHT引脚
13#define DHTTYPE DHT11
14// 初始化DHT11传感器
15DHT dht(DHTPIN, DHTTYPE);
16
17char MqttServer[] = "1.11.111.0"; 	//MQTT服务器的IP地址（阿里云公网IP）
18WiFiEspClient espClient;	// 初始化以太网客户端对象 -- WiFiEspClient.h
19PubSubClient client(espClient);	// 初始化MQTT库PubSubClient.h的对象
20
21SoftwareSerial mySerial(2, 3); // RX, TX，声明一个软串口
22
23int status = WL_IDLE_STATUS;
24unsigned long lastSend;
25
26void setup() {
27
28  Serial.begin(9600);
29  dht.begin();
30  
31  InitWiFi();                                // 连接WiFi
32  client.setServer( MqttServer, 1883 );      // 连接WiFi之后，连接MQTT服务器
33  
34  lastSend = 0;
35}
36
37void loop() {
38  status = WiFi.status();
39  if ( status != WL_CONNECTED) {
40    while ( status != WL_CONNECTED) {
41      Serial.print("[loop()]Attempting to connect to WPA SSID: ");
42      Serial.println(WIFI_AP);
43      // 连接WiFi热点
44      status = WiFi.begin(WIFI_AP, WIFI_PASSWORD);
45      delay(500);
46    }
47    Serial.println("[loop()]Connected to AP");
48  }
49
50  if ( !client.connected() ) {
51    reconnect();
52  }
53
54  if ( millis() - lastSend > 1000 ) { // 用于定时1秒钟发送一次数据
55    getAndSendTemperatureAndHumidityData(); // 获取温湿度数据发送到MQTT服务器上去
56    lastSend = millis();
57  }
58
59  client.loop();
60}
61
62/*
63 * 读取温湿度数据，然后发送到MQTT服务器上去
64 */
65void getAndSendTemperatureAndHumidityData()
66{
67  Serial.println("Collecting temperature data.");
68
69  // 大概250ms读取一次
70  float h = dht.readHumidity();
71  float t = dht.readTemperature();
72
73  // 查看是否读取温湿度失败的
74  if (isnan(h) || isnan(t)) {
75    Serial.println("Failed to read from DHT sensor!");
76    return;
77  }
78
79  Serial.print("Humidity: ");
80  Serial.print(h);
81  Serial.print(" %\t");
82  Serial.print("Temperature: ");
83  Serial.print(t);
84  Serial.print(" *C ");
85
86  String temperature = String(t);
87  String humidity = String(h);
88  
89  Serial.print( "Sending temperature and humidity : [" );
90  Serial.print( temperature ); Serial.print( "," );
91  Serial.print( humidity );
92  Serial.print( "]   -> " );
93
94  // 构建一个 JSON 格式的payload的字符串
95  String payload = "{";
96  payload += "\"temperature\":"; payload += temperature; payload += ",";
97  payload += "\"humidity\":"; payload += humidity;
98  payload += "}";
99  char attributes[100];
100  payload.toCharArray( attributes, 100 );
101 
102  client.publish( "DHT11", attributes );	//发布名字为“DHT11”的主题
103  Serial.print("[publish]-->>");
104  Serial.println( attributes );
105}
106/**
107 *Wifi连接初始化
108 */
109void InitWiFi()
110{
111  // 初始化软串口，软串口连接ESP模块
112  mySerial.begin(9600);
113  // 初始化ESP模块
114  WiFi.init(&mySerial);
115  // 检测WiFi模块在不在，宏定义：WL_NO_SHIELD = 255,WL_IDLE_STATUS = 0,
116  if (WiFi.status() == WL_NO_SHIELD) {
117    Serial.println("WiFi shield not present");
118    while (true);
119  }
120
121  Serial.println("[InitWiFi]Connecting to AP ...");
122  // 尝试连接WiFi网络
123  while ( status != WL_CONNECTED) {
124    Serial.print("[InitWiFi]Attempting to connect to WPA SSID: ");
125    Serial.println(WIFI_AP);
126    status = WiFi.begin(WIFI_AP, WIFI_PASSWORD);
127    delay(500);
128  }
129  Serial.println("[InitWiFi]Connected to AP");
130}
131
132/**
133 * MQTT客户端断线重连函数
134 */
135
136void reconnect() {
137  // 一直循环直到连接上MQTT服务器
138  while (!client.connected()) {
139    Serial.print("[reconnect]Connecting to MQTT Server ...");
140    // 尝试连接connect是个重载函数 (clientId, username, password)
141    if ( client.connect("mqttx_f4bb1f54", "zky", "135") ) {
142    //设置客户端ID（自定义），用户名，密码
143      Serial.println( "[DONE]" );
144    } else {
145      Serial.print( "[FAILED] [ mqtt connect error code = " );
146      Serial.print( client.state() );
147      Serial.println( " : retrying in 5 seconds]" );// Wait 5 seconds before retrying
148      delay( 5000 );
149    }
150  }
151}

三、效果
1、登录EMQ X Dashboard

2、连接客户端

3、订阅

4、发送和接收