CEF4Delphi初识

代码模块与职责

所有的代码都在src目录下，这会导致一上手的时候无法快速划分模块，不便于理解，如果分类然后放文件夹就会好一些。

最关键的部分在于uCEFApplication，是和dll链接的部分

uCEFInterfaces.pas，可以在这个文件内找到所有关于接口类型的声明，抽象了基本类型使用的接口，结构清晰。几乎是个功能都能找到对应的接口。和cef提供的接口有高度一致性。除了cef相关的接口外，还有自定义的一些工具接口。
uCEFClient.pas，继承自ICefClient，用于实现获取Handler的接口
uCEFTypes.pas，这个文件声明了大量的类型，但是不知道是不是所有的类型声明都在这里面。
uCEFChromium.pas，存放了TChromium的类型声明，是实现功能的关键类。
uCEFLoadHandler，存放了loadHandler相关类型，回调处理器的一个具体实现，还有很多其他的handler。
uCEFApplication.pas是核心，涉及到关键部分，有关键的类TCefApplication，加载了dll并获取函数，是使用CEF4Delphi的入口。

关键类型和关键接口

ICefBrowser：主要是浏览器级别的接口，获取frame，后退前进，中断加载等接口（浏览器进程的功能接口）；
ICefFrame：加载网页的对象，LoadUrl功能就是它提供的。可以看成加载网页的那个frame。针对于网页级别的接口（加载网页，复制粘贴等在网页级别的操作接口）；
ICefClient：接口，提供获取各种各样Handler的接口。其中Handler是回调处理器；
IChromiumEvents：关键接口，用于执行浏览器的关键操作，和handler回调处理器一起工作，实现连接libcef.dll的事件传递，该接口是自定义接口，非cef接口；

附件区域

事件传递流程

libcef.dll中注册的回调事件是如何通知到TChromium对象的呢？

在文件uCEFChromium.pas中，TChromium对象的常用工作流程CreateBrowser，会进行handler的注册

1function TChromium.CreateBrowser(      aParentHandle  : HWND;
2                                       aParentRect    : TRect;
3                                 const aWindowName    : ustring;
4                                    const aContext       : ICefRequestContext;
5                                 const aExtraInfo     : ICefDictionaryValue) : boolean;
6begin
7  Result := False;
8
9  try
10    // GlobalCEFApp.GlobalContextInitialized has to be TRUE before creating any browser
11    // even if you use a custom request context.
12    // If you create a browser in the initialization of your app, make sure you call this
13    // function when GlobalCEFApp.GlobalContextInitialized is TRUE.
14    // Use the GlobalCEFApp.OnContextInitialized event to know when
15    // GlobalCEFApp.GlobalContextInitialized is set to TRUE.
16
17    if not(csDesigning in ComponentState) and
18       not(FClosing)         and
19       (FBrowser     =  nil) and
20       (FBrowserId   =  0)   and
21       (GlobalCEFApp <> nil) and
22       GlobalCEFApp.GlobalContextInitialized  and
23       CreateClientHandler(aParentHandle = 0) then
24      begin
25        GetSettings(FBrowserSettings);
26        InitializeWindowInfo(aParentHandle, aParentRect, aWindowName);
27
28        if GlobalCEFApp.MultiThreadedMessageLoop then
29          Result := CreateBrowserHost(@FWindowInfo, FDefaultUrl, @FBrowserSettings, aExtraInfo, aContext)
30         else
31          Result := CreateBrowserHostSync(@FWindowInfo, FDefaultUrl, @FBrowserSettings, aExtraInfo, aContext);
32      end;
33  except
34    on e : exception do
35      if CustomExceptionHandler('TChromium.CreateBrowser', e) then raise;
36  end;
37end;

其中就有使用到CreateClientHandler这个函数（这里的Client说的就是继承自ICefClient类型，是否和cef的client类似还有待商榷）而CreateClientHandler会调用TCustomClientHandler.Create(Self);创建TCustomClientHandler的对象，而且这个函数的传参就是TChromium这个对象自身（因为TChromium继承自IChromiumEvents表示event处理机），见下述代码

1function TChromium.CreateClientHandler(aIsOSR : boolean) : boolean;
2begin
3  Result := False;
4
5  try
6    if (FHandler = nil) then
7      begin
8        FIsOSR   := aIsOsr;
9        FHandler := TCustomClientHandler.Create(Self);
10        Result   := True;
11      end;
12  except
13    on e : exception do
14      if CustomExceptionHandler('TChromium.CreateClientHandler', e) then raise;
15  end;
16end;

TCustomClientHandler的对象在构造的同事会再创建一堆handler的对象（我jio得TCustomClientHandler像是一个封装，封装了多个handler并对它们进行管理），以其中的OnLoadError为例（这个事件是当加载一个网页失败的时候会触发），TCustomClientHandler会创建一个TCustomLoadHandler类型的对象（当然依旧是把TChromium对象传递过去）

1constructor TCustomClientHandler.Create(const events : IChromiumEvents; aDevToolsClient : boolean);
2begin
3  inherited Create;
4
5  InitializeVars;
6
7  FEvents := Pointer(events);
8
9  if (events <> nil) then
10    begin
11      if aDevToolsClient then
12        begin
13          if events.MustCreateKeyboardHandler    then FKeyboardHandler    := TCustomKeyboardHandler.Create(events);
14        end
15       else
16        begin
17          if events.MustCreateLoadHandler        then FLoadHandler        := TCustomLoadHandler.Create(events);
18          if events.MustCreateFocusHandler       then FFocusHandler       := TCustomFocusHandler.Create(events);
19          if events.MustCreateContextMenuHandler then FContextMenuHandler := TCustomContextMenuHandler.Create(events);
20          if events.MustCreateDialogHandler      then FDialogHandler      := TCustomDialogHandler.Create(events);
21          if events.MustCreateKeyboardHandler    then FKeyboardHandler    := TCustomKeyboardHandler.Create(events);
22          if events.MustCreateDisplayHandler     then FDisplayHandler     := TCustomDisplayHandler.Create(events);
23          if events.MustCreateDownloadHandler    then FDownloadHandler    := TCustomDownloadHandler.Create(events);
24          if events.MustCreateJsDialogHandler    then FJsDialogHandler    := TCustomJsDialogHandler.Create(events);
25          if events.MustCreateLifeSpanHandler    then FLifeSpanHandler    := TCustomLifeSpanHandler.Create(events);
26          if events.MustCreateRenderHandler      then FRenderHandler      := TCustomRenderHandler.Create(events);
27          if events.MustCreateRequestHandler     then FRequestHandler     := TCustomRequestHandler.Create(events);
28          if events.MustCreateDragHandler        then FDragHandler        := TCustomDragHandler.Create(events);
29          if events.MustCreateFindHandler        then FFindHandler        := TCustomFindHandler.Create(events);
30          if events.MustCreateAudioHandler       then FAudioHandler       := TCustomAudioHandler.Create(events);
31        end;
32    end;
33end;

在文件uCEFLoadHandler.pas中，则定义了相关函数

1procedure TCustomLoadHandler.OnLoadError(const browser   : ICefBrowser;
2                                         const frame     : ICefFrame;
3                                               errorCode : TCefErrorCode;
4                                         const errorText : ustring;
5                                         const failedUrl : ustring);
6begin
7  if (FEvents <> nil) then IChromiumEvents(FEvents).doOnLoadError(browser, frame, errorCode, errorText, failedUrl);
8end;

其中FEvents就是TChromium的对象（类型转换后调用），这样就把TChromium对象的事件处理函数连接到这里来了。

之后再往前追溯。是如何把delphi的函数注册给C接口的dll的。在文件uCEFLoadHandler.pas中，有下面这么一个函数，命名风格和delphi截然不同，初步怀疑就是它被注册的

1procedure cef_load_handler_on_load_error(      self      : PCefLoadHandler;
2                                               browser   : PCefBrowser;
3                                               frame     : PCefFrame;
4                                               errorCode : TCefErrorCode;
5                                         const errorText : PCefString;
6                                         const failedUrl : PCefString); stdcall;
7var
8  TempObject : TObject;
9begin
10  TempObject := CefGetObject(self);
11
12  if (TempObject <> nil) and (TempObject is TCefLoadHandlerOwn) then
13    TCefLoadHandlerOwn(TempObject).OnLoadError(TCefBrowserRef.UnWrap(browser),
14                                               TCefFrameRef.UnWrap(frame),
15                                               errorCode,
16                                               CefString(errorText),
17                                               CefString(failedUrl));
18end;

它唯一被引用的地方如下

1constructor TCefLoadHandlerOwn.Create;
2begin
3  inherited CreateData(SizeOf(TCefLoadHandler));
4
5  with PCefLoadHandler(FData)^ do
6    begin
7      on_loading_state_change := {$IFDEF FPC}@{$ENDIF}cef_load_handler_on_loading_state_change;
8      on_load_start           := {$IFDEF FPC}@{$ENDIF}cef_load_handler_on_load_start;
9      on_load_end             := {$IFDEF FPC}@{$ENDIF}cef_load_handler_on_load_end;
10      on_load_error           := {$IFDEF FPC}@{$ENDIF}cef_load_handler_on_load_error;
11    end;
12end;

inherited CreateData(SizeOf(TCefLoadHandler));代表调用父类的CreateData函数，主要目的是开辟一块内存空间，大小是TCefLoadHandler类型大小那么大的内存空间，而FData就是指向那块内存的地址。

其中on_load_error的定义如下on_load_error : procedure(self: PCefLoadHandler; browser: PCefBrowser; frame: PCefFrame; errorCode: TCefErrorCode; const errorText, failedUrl: PCefString); stdcall; 是一个函数对象

而TCefLoadHandlerOwn则是继承自下面这个类型

1  // /include/capi/cef_load_handler_capi.h (cef_load_handler_t)
2  TCefLoadHandler = record
3    base                    : TCefBaseRefCounted;
4    on_loading_state_change : procedure(self: PCefLoadHandler; browser: PCefBrowser; isLoading, canGoBack, canGoForward: Integer); stdcall;
5    on_load_start           : procedure(self: PCefLoadHandler; browser: PCefBrowser; frame: PCefFrame; transition_type: TCefTransitionType); stdcall;
6    on_load_end             : procedure(self: PCefLoadHandler; browser: PCefBrowser; frame: PCefFrame; httpStatusCode: Integer); stdcall;
7    on_load_error           : procedure(self: PCefLoadHandler; browser: PCefBrowser; frame: PCefFrame; errorCode: TCefErrorCode; const errorText, failedUrl: PCefString); stdcall;
8  end;

根据这里的注释，找到了cef中的c接口描述文件，发现TCefLoadHandler类型和c接口定义的_cef_load_handler_t结构体一致，到此处就基本能确定了，TCefLoadHandler就是和C接口对接的注册函数的类型。

代码模块与职责

关键类型和关键接口

附件区域

事件传递流程

评论区

相关推荐